Consolidate recipe content from meta-freescale-distro

recipes-devtools/half/half_2.1.0.bb

@@ -0,0 +1,19 @@
+SUMMARY = "C++ library for half precision floating point arithmetics"
+DESCRIPTION = "half is a C++ header-only library to provide an IEEE-754 conformant \ 
+half-precision floating point type along with corresponding arithmetic operators, \
+type conversions and common mathematical functions."
+
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://LICENSE.txt;md5=813a6278831975d26c115ed6f9c21831"
+
+SRC_URI = "https://sourceforge.net/projects/half/files/half/${PV}/${BP}.zip"
+SRC_URI[sha256sum] = "ad1788afe0300fa2b02b0d1df128d857f021f92ccf7c8bddd07812685fa07a25"
+
+S = "${UNPACKDIR}"
+
+do_install () {
+    install -d ${D}${includedir}
+    cp -r ${S}/include/* ${D}${includedir}
+}
+
+ALLOW_EMPTY:${PN} = "1"

recipes-devtools/stb/stb_git.bb

@@ -0,0 +1,18 @@
+SUMMARY = "single-file public domain (or MIT licensed) libraries for C/C++"
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://stb.h;beginline=14418;endline=14433;md5=b10975d4c8155af1811ab611586f01d2"
+
+PV = "0.0+git${SRCPV}"
+
+SRCREV = "f67165c2bb2af3060ecae7d20d6f731173485ad0"
+SRC_URI = "git://github.com/nothings/stb.git;protocol=https;branch=master"
+
+do_install() {
+    install -d ${D}${includedir}
+    for hdr in ${S}/*.h; do
+        install -m 0644 $hdr ${D}${includedir}
+    done
+}
+
+# This is a header-only library, so the main package will be empty.
+ALLOW_EMPTY:${PN} = "1"

recipes-fsl/fsl-rc-local/fsl-rc-local.bb

@@ -0,0 +1,23 @@
+# Copyright (C) 2012 O.S. Systems Software LTDA.
+
+DESCRIPTION = "Extra files for fsl-gui-image"
+LICENSE = "LGPL-2.0-only"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=39ec502560ab2755c4555ee8416dfe42"
+
+SRC_URI = "file://rc.local.etc \
+           file://rc.local.init \
+           file://LICENSE"
+
+S = "${UNPACKDIR}"
+
+inherit update-rc.d
+
+INITSCRIPT_NAME = "rc.local"
+INITSCRIPT_PARAMS = "start 99 2 3 4 5 ."
+
+do_install () {
+    install -d ${D}/${sysconfdir}/init.d
+    install -m 755 ${S}/rc.local.etc ${D}/${sysconfdir}/rc.local
+    install -m 755 ${S}/rc.local.init ${D}/${sysconfdir}/init.d/rc.local
+
+}

recipes-fsl/fsl-rc-local/fsl-rc-local/LICENSE

@@ -0,0 +1 @@
+All content inside fsl-rc-local package are distributed under GPLv2 license

recipes-fsl/fsl-rc-local/fsl-rc-local/rc.local.etc

@@ -0,0 +1,14 @@
+#!/bin/sh -e
+#
+# rc.local
+#
+# This script is executed at the end of each multiuser runlevel.
+# Make sure that the script will "exit 0" on success or any other
+# value on error.
+#
+# In order to enable or disable this script just change the execution
+# bits.
+#
+# By default this script does nothing.
+
+exit 0

recipes-fsl/fsl-rc-local/fsl-rc-local/rc.local.init

@@ -0,0 +1,36 @@
+#! /bin/sh
+### BEGIN INIT INFO
+# Provides:          rc.local
+# Required-Start:    $all
+# Required-Stop:
+# Default-Start:     2 3 4 5
+# Default-Stop:
+# Short-Description: Run /etc/rc.local if it exist
+### END INIT INFO
+
+PATH=/sbin:/usr/sbin:/bin:/usr/bin
+
+do_start() {
+	if [ -x /etc/rc.local ]; then
+		echo -n "Running local boot scripts (/etc/rc.local)"
+		/etc/rc.local
+		[ $? = 0 ] && echo "." || echo "error"
+		return $ES
+	fi
+}
+
+case "$1" in
+    start)
+	do_start
+        ;;
+    restart|reload|force-reload)
+        echo "Error: argument '$1' not supported" >&2
+        exit 3
+        ;;
+    stop)
+        ;;
+    *)
+        echo "Usage: $0 start|stop" >&2
+        exit 3
+        ;;
+esac

recipes-fsl/images/fsl-image-machine-test.bb

@@ -0,0 +1,31 @@
+DESCRIPTION = "A console-only image that includes gstreamer packages, \
+Freescale's multimedia packages (VPU and GPU) when available, and \
+test and benchmark applications."
+
+IMAGE_FEATURES += " \
+    ${@bb.utils.contains('DISTRO_FEATURES', 'wayland', '', \
+       bb.utils.contains('DISTRO_FEATURES',     'x11', 'x11-base', \
+                                                       '', d), d)} \
+    debug-tweaks \
+    tools-testapps \
+    tools-profile \
+"
+
+LICENSE = "MIT"
+
+inherit core-image
+
+CORE_IMAGE_EXTRA_INSTALL += " \
+    packagegroup-fsl-gstreamer1.0 \
+    packagegroup-fsl-gstreamer1.0-full \
+    packagegroup-fsl-tools-gpu \
+    packagegroup-fsl-tools-gpu-external \
+    packagegroup-fsl-tools-testapps \
+    packagegroup-fsl-tools-benchmark \
+    ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', \
+                         'firmwared', '', d)} \
+    ${@bb.utils.contains('DISTRO_FEATURES', 'wayland', \
+                         'weston weston-init', '', d)} \
+    ${@bb.utils.contains('DISTRO_FEATURES', 'x11 wayland', \
+                         'weston-xwayland xterm', '', d)} \
+"

recipes-fsl/images/fsl-image-multimedia-full.bb

@@ -0,0 +1,8 @@
+# This image extends fsl-image-multimedia with additional
+# gstreamer plugins
+
+require fsl-image-multimedia.bb
+
+CORE_IMAGE_EXTRA_INSTALL += " \
+    packagegroup-fsl-gstreamer1.0-full \
+"

recipes-fsl/images/fsl-image-multimedia.bb

@@ -0,0 +1,30 @@
+DESCRIPTION = "A console-only image that includes gstreamer packages and \
+Freescale's multimedia packages (VPU and GPU) when available for the specific \
+machine."
+
+IMAGE_FEATURES += "\
+    ${@bb.utils.contains('DISTRO_FEATURES', 'wayland', 'weston', \
+       bb.utils.contains('DISTRO_FEATURES',     'x11', 'x11-base', \
+                                                       '', d), d)} \
+"
+
+LICENSE = "MIT"
+
+inherit core-image
+
+CORE_IMAGE_EXTRA_INSTALL += " \
+    packagegroup-fsl-tools-gpu \
+    packagegroup-fsl-gstreamer1.0 \
+    packagegroup-imx-tools-audio \
+    ${@bb.utils.contains('DISTRO_FEATURES', 'wayland', \
+                         'weston weston-init weston-examples \
+                          gtk+3-demo', '', d)} \
+    ${@bb.utils.contains('DISTRO_FEATURES', 'x11 wayland', \
+                         'weston-xwayland xterm', '', d)} \
+"
+
+PACKAGE_IMX_TO_REMOVE = ""
+PACKAGE_IMX_TO_REMOVE:imxgpu2d = "gtk+3-demo"
+PACKAGE_IMX_TO_REMOVE:imxgpu3d = ""
+
+CORE_IMAGE_EXTRA_INSTALL:remove = "${PACKAGE_IMX_TO_REMOVE}"

recipes-fsl/images/fsl-image-network-full-cmdline.bb

@@ -0,0 +1,22 @@
+DESCRIPTION = "A console-only image that includes full cmdline and \
+Freescale's networking packages (QorIQ DPAA/DPAA2) when available."
+
+IMAGE_FEATURES += " \
+    debug-tweaks \
+    tools-profile \
+"
+
+LICENSE = "MIT"
+
+CORE_IMAGE_EXTRA_INSTALL:append = "\
+    packagegroup-core-boot \
+    packagegroup-core-full-cmdline \
+    packagegroup-fsl-network \
+"
+
+# SPI Nor-Flash
+NETWORK_TOOLS:append:fsl-lsch3 = "\
+    mtd-utils \
+"
+
+inherit core-image

recipes-fsl/packagegroups/packagegroup-fsl-gstreamer1.0-commercial.bb

@@ -0,0 +1,17 @@
+DESCRIPTION = "Package group used by FSL Community to provide audio and video plugins \
+that are subject to restricted licensing and/or royalties and thus require \
+the 'commercial' license whitelist flag"
+SUMMARY = "FSL Community package group - set of GStreamer 1.0 plugins with commercial licence flag"
+LICENSE_FLAGS = "commercial"
+
+inherit packagegroup
+
+RDEPENDS:${PN} = " \
+    packagegroup-fsl-gstreamer1.0 \
+"
+
+# Plugins from the -ugly collection which require the "commercial" flag in LICENSE_FLAGS_ACCEPTED to be set
+RDEPENDS:${PN} = " \
+    gstreamer1.0-plugins-ugly-asf \
+    gstreamer1.0-libav \
+"

recipes-fsl/packagegroups/packagegroup-fsl-gstreamer1.0-full.bb

@@ -0,0 +1,15 @@
+DESCRIPTION = "Package group used by FSL Community to provide all GStreamer plugins from the \
+base, good, and bad packages, as well as the ugly and libav ones if commercial packages \
+are whitelisted, and plugins for the required hardware acceleration (if supported by the SoC)."
+SUMMARY = "FSL Community package group - full set of all GStreamer 1.0 plugins"
+
+inherit packagegroup
+
+RDEPENDS:${PN} = " \
+    packagegroup-fsl-gstreamer1.0 \
+    ${@bb.utils.contains('LICENSE_FLAGS_ACCEPTED', 'commercial', 'packagegroup-fsl-gstreamer1.0-commercial', '', d)} \
+    gstreamer1.0-plugins-base-meta \
+    gstreamer1.0-plugins-good-meta \
+    gstreamer1.0-plugins-bad-meta \
+    ${@bb.utils.contains('LICENSE_FLAGS_ACCEPTED', 'commercial', 'gstreamer1.0-plugins-ugly-meta', '', d)} \
+"

recipes-fsl/packagegroups/packagegroup-fsl-gstreamer1.0.bb

@@ -0,0 +1,118 @@
+DESCRIPTION = "Package group used by FSL Community to provide audio, video, networking and debug \
+GStreamer plugins with the required hardware acceleration (if supported by the SoC)."
+SUMMARY = "FSL Community package group - set of commonly used GStreamer 1.0 plugins"
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+inherit packagegroup
+
+PACKAGES += " \
+    ${PN}-base \
+    ${PN}-audio \
+    ${PN}-video \
+    ${PN}-video-bad \
+    ${PN}-debug \
+    ${PN}-network-base \
+    ${PN}-network \
+"
+
+MACHINE_GSTREAMER_1_0_PLUGIN ?= ""
+
+RDEPENDS:${PN} = " \
+    ${PN}-audio \
+    ${PN}-video \
+    ${PN}-network-base \
+    ${PN}-debug \
+"
+
+# List of X11 specific plugins
+GST_X11_PACKAGES = " \
+    gstreamer1.0-plugins-base-ximagesink \
+    gstreamer1.0-plugins-base-xvimagesink \
+"
+
+# List of Wayland specific plugins
+GST_WAYLAND_PACKAGES = " \
+    gstreamer1.0-plugins-bad-waylandsink \
+"
+
+# basic plugins required in virtually every pipeline
+RDEPENDS:${PN}-base = " \
+    gstreamer1.0 \
+    gstreamer1.0-plugins-base-playback \
+    ${@bb.utils.contains('DISTRO_FEATURES', 'alsa', 'gstreamer1.0-plugins-base-alsa', '', d)} \
+    gstreamer1.0-plugins-base-audioconvert \
+    gstreamer1.0-plugins-base-audioresample \
+    gstreamer1.0-plugins-base-gio \
+    gstreamer1.0-plugins-base-typefindfunctions \
+    gstreamer1.0-plugins-base-videoconvertscale \
+    gstreamer1.0-plugins-base-volume \
+    gstreamer1.0-plugins-good-autodetect \
+    ${MACHINE_GSTREAMER_1_0_PLUGIN} \
+    ${@bb.utils.contains("MACHINE_GSTREAMER_1_0_PLUGIN", "imx-gst1.0-plugin", "imx-gst1.0-plugin-tools", "", d)} \
+"
+
+RRECOMMENDS:${PN}-base = " \
+    ${@bb.utils.contains('DISTRO_FEATURES', 'x11', '${GST_X11_PACKAGES}', \
+                          bb.utils.contains('DISTRO_FEATURES', 'wayland', \
+                                            '${GST_WAYLAND_PACKAGES}', '', d), d)} \
+"
+
+# Basic audio plugins: parsers, demuxers, decoders
+RDEPENDS:${PN}-audio = " \
+    ${PN}-base \
+    gstreamer1.0-plugins-base-ogg \
+    gstreamer1.0-plugins-good-audioparsers \
+    gstreamer1.0-plugins-good-flac \
+    gstreamer1.0-plugins-good-icydemux \
+    gstreamer1.0-plugins-good-id3demux \
+    gstreamer1.0-plugins-good-speex \
+    gstreamer1.0-plugins-good-wavparse \
+"
+
+# Basic video plugins: parsers, demuxers
+RDEPENDS:${PN}-video = " \
+    ${PN}-base \
+    gstreamer1.0-plugins-base-subparse \
+    gstreamer1.0-plugins-base-theora \
+    gstreamer1.0-plugins-good-avi \
+    gstreamer1.0-plugins-good-flv \
+    gstreamer1.0-plugins-good-isomp4 \
+    gstreamer1.0-plugins-good-matroska \
+"
+
+RRECOMMENDS:${PN}-video = " \
+    ${PN}-audio \
+"
+
+# Additional video plugins from the -bad collection
+RDEPENDS:${PN}-video-bad = " \
+    ${PN}-video \
+    gstreamer1.0-plugins-bad-mpegpsdemux \
+    gstreamer1.0-plugins-bad-mpegtsdemux \
+    gstreamer1.0-plugins-bad-videoparsersbad \
+"
+
+# Plugins used for diagnostics and debugging of pipelines
+RDEPENDS:${PN}-debug = " \
+    ${PN}-base \
+    gstreamer1.0-plugins-base-audiotestsrc \
+    gstreamer1.0-plugins-base-videotestsrc \
+    gstreamer1.0-plugins-good-debug \
+    gstreamer1.0-plugins-good-navigationtest \
+"
+
+# Basic networking plugins required by most pipelines that receive and/or send data
+RDEPENDS:${PN}-network-base = " \
+    gstreamer1.0-plugins-base-tcp \
+    gstreamer1.0-plugins-good-soup \
+    gstreamer1.0-plugins-good-udp \
+"
+
+# Additional networking plugins
+RDEPENDS:${PN}-network = " \
+    ${PN}-network-base \
+    gstreamer1.0-plugins-good-rtp \
+    gstreamer1.0-plugins-good-rtpmanager \
+    gstreamer1.0-plugins-good-rtsp \
+"