Add resampling extension

Project.toml

@@ -15,7 +15,14 @@ RecipesBase = "3cdcf5f2-1ef4-517c-9805-6587b60abb01"
 Unitful = "1986cc42-f94f-5a68-af5c-568840ba703d"
 UnitfulAstro = "6112ee07-acf9-5e0f-b108-d242c714bf9f"
 
+[weakdeps]
+DataInterpolations = "82cc6244-b520-54b8-b5a6-8a565e85f1d0"
+
+[extensions]
+DataInterpolationsExt = "DataInterpolations"
+
 [compat]
+DataInterpolations = "8"
 DustExtinction = ">=0.6.0"
 LinearAlgebra = "1.5"
 Measurements = "2"

ext/DataInterpolationsExt.jl

@@ -0,0 +1,36 @@
+module DataInterpolationsExt
+
+using Spectra: Spectra, Spectrum, spectrum, wave, flux
+import Spectra: resample
+using DataInterpolations: AbstractInterpolation
+
+function Spectra.resample(spec::Spectrum, wave_sampled, interp::AbstractInterpolation)
+    # p = sortperm(spec.wave) # x-scale must be monitonically increasing; not being used
+    flux_sampled = interp(wave_sampled)
+    return spectrum(wave_sampled, flux_sampled; meta = spec.meta)
+end
+
+"""
+    resample(spec::Spectrum, wave_sampled, interp::Type{<:DataInterpolations.AbstractInterpolation}; kws...)
+Constructs an interpolator of type `interp` from the provided spectrum `spec` and evaluates it at `wave_sampled`, returning a `Spectrum`. The `kws...` control extrapolation and are passed through to the interpolator.
+
+```jldoctest
+julia> using Spectra, DataInterpolations
+
+julia> spec = spectrum([2, 4, 12, 16, 20], [1, 3, 7, 6, 20]);
+
+julia> wave_sampled = [1, 5, 9, 13, 14, 17, 21, 22, 23];
+
+julia> resample(spec, wave_sampled, LinearInterpolation; extrapolation = ExtrapolationType.Constant)
+Spectrum(Int64, Float64)
+```
+"""
+function Spectra.resample(spec::Spectrum, wave_sampled, interp::Type{<:AbstractInterpolation}; kws...)
+    # Not sure if we have to check wave is monotonically increasing or if that is guaranteed by the constructor?
+    p = sortperm(wave(spec))
+    itp = interp(flux(spec)[p], wave(spec)[p]; kws...)
+    flux_sampled = itp.(wave_sampled)
+    return spectrum(wave_sampled, flux_sampled; meta = spec.meta)
+end
+
+end # module

src/Spectra.jl

@@ -6,6 +6,8 @@ export AbstractSpectrum, spectrum
 export blackbody
 # transforms/redden.jl
 export redden, redden!, deredden, deredden!
+# resampling: ../ext/DataInterpolationsExt.jl
+export resample
 
 using RecipesBase: @recipe
 using Measurements: Measurements, Measurement
@@ -91,6 +93,36 @@ function spectrum(wave::AbstractMatrix{<:Quantity}, flux::AbstractMatrix{<:Quant
     EchelleSpectrum(wave, flux, Dict{Symbol,Any}(kwds))
 end
 
+# Stub
+"""
+    function resample(spec, wave_sampled, interp)
+
+Resample a spectrum onto the given wavelength grid `wave_sampled` using the supplied interpolator `interp`. Currently supports interpolators from the [DataInterpolations.jl](https://github.com/SciML/DataInterpolations.jl) package.
+
+# Examples
+
+```julia-repl
+julia> using DataInterpolations
+
+julia> spec = spectrum([2, 4, 12, 16, 20], [1, 3, 7, 6, 20]);
+
+julia> wave_sampled = [1, 5, 9, 13, 14, 17, 21, 22, 23];
+
+ # BYO interpolator
+julia> interp = LinearInterpolation(spec.flux, spec.wave; extrapolation = ExtrapolationType.Constant);
+
+julia> spec_sampled = resample(spec, wave_sampled, interp);
+```
+"""
+function resample(spec, wave_sampled, interp)
+    error("""Supported interpolation package not loaded. Please try adding one of the supported interpolation packages below:
+
+    - DataInterpolations.jl
+
+    PRs to add additional interpolation packages are welcome!
+    """)
+end
+
 # tools
 include("utils.jl")
 include("transforms/transforms.jl")