wbg: add module

modules/misc/news/2026/07/2026-07-29_03-27-10.nix

@@ -0,0 +1,9 @@
+{ pkgs, ... }: {
+  time = "2026-07-29T02:27:10+00:00";
+  condition = pkgs.stdenv.hostPlatform.isLinux;
+  message = ''
+    A new module is available: 'services.wbg'.
+
+    wbg is a super simple wallpaper application for Wayland compositors.
+  '';
+}

modules/services/wbg.nix

@@ -0,0 +1,71 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}:
+
+let
+  inherit (lib)
+    mkEnableOption
+    mkOption
+    mkIf
+    getExe
+    optional
+    escapeShellArgs
+    mkPackageOption
+    types
+    ;
+
+  cfg = config.services.wbg;
+in
+{
+  meta.maintainers = with lib.maintainers; [ yarn ];
+
+  options.services.wbg = {
+    enable = mkEnableOption "wbg, a super simple wallpaper application for Wayland compositors";
+    package = mkPackageOption pkgs "wbg" { };
+
+    stretch = mkOption {
+      type = types.bool;
+      default = false;
+      description = "Whether to stretch the wallpaper to fill the screen.";
+    };
+
+    image = mkOption {
+      type = types.either types.path types.str;
+      description = "Path to the wallpaper image.";
+    };
+
+    extraArgs = mkOption {
+      type = types.listOf types.str;
+      default = [ ];
+      description = "Extra command-line arguments to pass to wbg.";
+    };
+  };
+
+  config = mkIf cfg.enable {
+    home.packages = [ cfg.package ];
+
+    systemd.user.services.wbg = {
+      Unit = {
+        ConditionEnvironment = "WAYLAND_DISPLAY";
+        Description = "wbg";
+        After = [ config.wayland.systemd.target ];
+        PartOf = [ config.wayland.systemd.target ];
+      };
+
+      Service = {
+        ExecStart = escapeShellArgs (
+          [ (getExe cfg.package) ] ++ optional cfg.stretch "-s" ++ [ (toString cfg.image) ] ++ cfg.extraArgs
+        );
+        Restart = "on-failure";
+        RestartSec = 10;
+      };
+
+      Install = {
+        WantedBy = [ config.wayland.systemd.target ];
+      };
+    };
+  };
+}

tests/modules/services/wbg/basic.nix

@@ -0,0 +1,14 @@
+_:
+
+{
+  services.wbg = {
+    enable = true;
+    image = "/tmp/wallpaper.png";
+  };
+
+  nmt.script = ''
+    serviceFile=home-files/.config/systemd/user/wbg.service
+    assertFileExists $serviceFile
+    assertFileContent $serviceFile ${./basic.service}
+  '';
+}

tests/modules/services/wbg/basic.service

@@ -0,0 +1,13 @@
+[Install]
+WantedBy=graphical-session.target
+
+[Service]
+ExecStart=@wbg@/bin/wbg /tmp/wallpaper.png
+Restart=on-failure
+RestartSec=10
+
+[Unit]
+After=graphical-session.target
+ConditionEnvironment=WAYLAND_DISPLAY
+Description=wbg
+PartOf=graphical-session.target

tests/modules/services/wbg/default.nix

@@ -0,0 +1,7 @@
+{ lib, pkgs, ... }:
+
+lib.optionalAttrs pkgs.stdenv.hostPlatform.isLinux {
+  wbg-basic = ./basic.nix;
+  wbg-stretch = ./stretch.nix;
+  wbg-extra-args = ./extra-args.nix;
+}

tests/modules/services/wbg/extra-args.nix

@@ -0,0 +1,18 @@
+_:
+
+{
+  services.wbg = {
+    enable = true;
+    image = "/tmp/wallpaper.png";
+    extraArgs = [
+      "-d"
+      "2"
+    ];
+  };
+
+  nmt.script = ''
+    serviceFile=home-files/.config/systemd/user/wbg.service
+    assertFileExists $serviceFile
+    assertFileContent $serviceFile ${./extra-args.service}
+  '';
+}

tests/modules/services/wbg/extra-args.service

@@ -0,0 +1,13 @@
+[Install]
+WantedBy=graphical-session.target
+
+[Service]
+ExecStart=@wbg@/bin/wbg /tmp/wallpaper.png -d 2
+Restart=on-failure
+RestartSec=10
+
+[Unit]
+After=graphical-session.target
+ConditionEnvironment=WAYLAND_DISPLAY
+Description=wbg
+PartOf=graphical-session.target

tests/modules/services/wbg/stretch.nix

@@ -0,0 +1,15 @@
+_:
+
+{
+  services.wbg = {
+    enable = true;
+    image = "/tmp/wallpaper.png";
+    stretch = true;
+  };
+
+  nmt.script = ''
+    serviceFile=home-files/.config/systemd/user/wbg.service
+    assertFileExists $serviceFile
+    assertFileContent $serviceFile ${./stretch.service}
+  '';
+}

tests/modules/services/wbg/stretch.service

@@ -0,0 +1,13 @@
+[Install]
+WantedBy=graphical-session.target
+
+[Service]
+ExecStart=@wbg@/bin/wbg -s /tmp/wallpaper.png
+Restart=on-failure
+RestartSec=10
+
+[Unit]
+After=graphical-session.target
+ConditionEnvironment=WAYLAND_DISPLAY
+Description=wbg
+PartOf=graphical-session.target