module/pomo: init

modules/lib/maintainers.nix

@@ -103,12 +103,6 @@
     github = "CarlosLoboxyz";
     githubId = 86011416;
   };
-  ckgxrg = {
-    name = "ckgxrg";
-    email = "ckgxrg@ckgxrg.io";
-    github = "ckgxrg-salt";
-    githubId = 165614491;
-  };
   csanthiago = {
     name = "csanthiago";
     email = "git@csanthiago.dev";
@@ -499,6 +493,11 @@
     github = "prescientmoon";
     githubId = 39400800;
   };
+  rachitvrma = {
+    name = "Rachit Kumar Verma";
+    github = "rachitvrma";
+    githubId = 155641117;
+  };
   rasmus-kirk = {
     name = "Rasmus Kirk";
     email = "mail@rasmuskirk.com";
@@ -529,12 +528,6 @@
     github = "Rosuavio";
     githubId = 7164552;
   };
-  rsahwe = {
-    name = "rsahwe";
-    email = "rsahwe@gmx.net";
-    github = "rsahwe";
-    githubId = 201613730;
-  };
   rszamszur = {
     name = "Radosław Szamszur";
     email = "radoslawszamszur@gmail.com";

modules/misc/news/2026/07/2026-07-28_20-12-31.nix

@@ -0,0 +1,12 @@
+{
+  time = "2026-07-28T14:42:31+00:00";
+  condition = true;
+  message = ''
+    A new module is available: 'programs.pomo'
+
+    Customizable TUI Pomodoro timer with ASCII art, progress bar,
+    desktop notifications, and productivity statistics.
+
+    See <https://github.com/Bahaaio/pomo> for more details.
+  '';
+}

modules/programs/pomo.nix

@@ -0,0 +1,74 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}:
+let
+  inherit (lib)
+    mkIf
+    mkEnableOption
+    mkOption
+    mkPackageOption
+    ;
+  cfg = config.programs.pomo;
+  yamlFormat = pkgs.formats.yaml { };
+in
+{
+  meta.maintainers = with lib.hm.maintainers; [
+    rachitvrma
+  ];
+
+  options.programs.pomo = {
+    enable = mkEnableOption ''
+      pomo, a TUI Pomodoro timer with ASCII Art, progress bar,
+      desktop notifications, and productivity stats.
+    '';
+
+    package = mkPackageOption pkgs "pomo" { nullable = true; };
+
+    settings = mkOption {
+      inherit (yamlFormat) type;
+
+      default = { };
+      defaultText = lib.literalExpression "{ }";
+
+      example = lib.literalExpression ''
+        {
+          onSessionEnd = "ask";
+
+          asciiArt = {
+            enabled = true;
+            font = "mono12";
+            color = "#5A56E0";
+          };
+
+          work = {
+            duration = "25m";
+            title = "work session";
+            notification = {
+              enabled = true;
+              urgent = false;
+              title = "work finished 🎉";
+              message = "time to take a break";
+            };
+          };
+        }
+      '';
+
+      description = ''
+        Configuration written to
+        {file}`$XDG_CONFIG_HOME/pomo/pomo.yml`
+        See <https://github.com/Bahaaio/pomo/blob/main/pomo.yaml>
+      '';
+    };
+  };
+
+  config = mkIf cfg.enable {
+    home.packages = mkIf (cfg.package != null) [ cfg.package ];
+
+    xdg.configFile."pomo/pomo.yaml" = mkIf (cfg.settings != { }) {
+      source = yamlFormat.generate "hm_pomo.yaml" cfg.settings;
+    };
+  };
+}

modules/programs/rizin.nix

@@ -9,7 +9,7 @@ let
 in
 {
   meta.maintainers = [
-    lib.hm.maintainers.rsahwe
+    lib.maintainers.rsahwe
   ];
 
   options = {

modules/services/linux-wallpaperengine.nix

@@ -10,7 +10,7 @@ let
   cfg = config.services.linux-wallpaperengine;
 in
 {
-  meta.maintainers = [ lib.hm.maintainers.ckgxrg ];
+  meta.maintainers = [ lib.maintainers.ckgxrg ];
 
   options.services.linux-wallpaperengine = {
     enable = lib.mkEnableOption "linux-wallpaperengine, an implementation of Wallpaper Engine functionality";

tests/modules/programs/pomo/default.nix

@@ -0,0 +1,4 @@
+{
+  pomo-empty-settings = ./empty-settings.nix;
+  pomo-example-settings = ./example-settings.nix;
+}

tests/modules/programs/pomo/empty-settings.nix

@@ -0,0 +1,6 @@
+{
+  programs.pomo.enable = true;
+  nmt.script = ''
+    assertPathNotExists home-files/.config/pomo
+  '';
+}

tests/modules/programs/pomo/example-settings-expected.yaml

@@ -0,0 +1,25 @@
+asciiArt:
+  color: '#5A56E0'
+  enabled: true
+  font: mono12
+break:
+  duration: 5m
+  notification:
+    enabled: true
+    message: back to work!
+    title: break over 😴
+    urgent: false
+  title: break session
+longBreak:
+  after: 4
+  duration: 20m
+  enabled: true
+onSessionEnd: ask
+work:
+  duration: 25m
+  notification:
+    enabled: true
+    message: time to take a break
+    title: work finished 🎉
+    urgent: false
+  title: work session

tests/modules/programs/pomo/example-settings.nix

@@ -0,0 +1,45 @@
+{ config, ... }: {
+  programs.pomo = {
+    enable = true;
+    package = config.lib.test.mkStubPackage { };
+    settings = {
+      onSessionEnd = "ask";
+      asciiArt = {
+        enabled = true;
+        font = "mono12";
+        color = "#5A56E0";
+      };
+      work = {
+        duration = "25m";
+        title = "work session";
+        notification = {
+          enabled = true;
+          urgent = false;
+          title = "work finished 🎉";
+          message = "time to take a break";
+        };
+      };
+      break = {
+        duration = "5m";
+        title = "break session";
+        notification = {
+          enabled = true;
+          urgent = false;
+          title = "break over 😴";
+          message = "back to work!";
+        };
+      };
+      longBreak = {
+        enabled = true;
+        after = 4;
+        duration = "20m";
+      };
+    };
+  };
+  nmt.script = ''
+    local configFile=home-files/.config/pomo/pomo.yaml
+
+    assertFileExists $configFile
+    assertFileContent $configFile ${./example-settings-expected.yaml}
+  '';
+}