[WIP] Conditions Hierarchy

Pipfile

@@ -15,7 +15,7 @@ ape-infura = "*"
 ape-foundry = "*"
 flake8 = "*"
 isort = "*"
-nucypher-core = "==0.15.0"
+nucypher-core = { git = "https://github.com/nucypher/nucypher-core.git", ref = "main", subdirectory = "nucypher-core-python" }
 pre-commit = "*"
 tox = "*"
 pyyaml = "*"

ape-config.yaml

@@ -38,7 +38,7 @@ polygon:
   mainnet:
     transaction_acceptance_timeout: 600 # 10 minutes
   amoy:
-    gas_limit: auto  # because we are cutting it close with Coordinator
+    gas_limit: auto # because we are cutting it close with Coordinator
 
 foundry:
   host: auto
@@ -65,5 +65,7 @@ etherscan:
     rate_limit: 5
 
 test:
+  provider:
+    chain_id: 131277322940537 # ensure ape doesn't change chain id to 1337
   mnemonic: test test test test test test test test test test test junk
-  number_of_accounts: 40
+  number_of_accounts: 70

contracts/contracts/coordination/Coordinator.sol

@@ -131,6 +131,7 @@ contract Coordinator is Initializable, AccessControlDefaultAdminRulesUpgradeable
 
     bytes32 public constant FEE_MODEL_MANAGER_ROLE = keccak256("FEE_MODEL_MANAGER_ROLE");
     bytes32 public constant HANDOVER_SUPERVISOR_ROLE = keccak256("HANDOVER_SUPERVISOR_ROLE");
+    uint256 public constant DECRYPTION_REQUEST_KEY_LENGTH = 42;
 
     ITACoChildApplication public immutable application;
     uint96 private immutable minAuthorization; // TODO use child app for checking eligibility
@@ -495,7 +496,7 @@ contract Coordinator is Initializable, AccessControlDefaultAdminRulesUpgradeable
         );
 
         require(
-            decryptionRequestStaticKey.length == 42,
+            decryptionRequestStaticKey.length == DECRYPTION_REQUEST_KEY_LENGTH,
             "Invalid length for decryption request static key"
         );
 
@@ -584,7 +585,7 @@ contract Coordinator is Initializable, AccessControlDefaultAdminRulesUpgradeable
         require(isRitualActive(ritualId), "Ritual is not active");
         require(transcript.length > 0, "Parameters can't be empty");
         require(
-            decryptionRequestStaticKey.length == 42,
+            decryptionRequestStaticKey.length == DECRYPTION_REQUEST_KEY_LENGTH,
             "Invalid length for decryption request static key"
         );
 

contracts/contracts/coordination/IL1Sender.sol

@@ -0,0 +1,16 @@
+// SPDX-License-Identifier: AGPL-3.0-or-later
+
+pragma solidity ^0.8.0;
+
+/**
+ * @title IL1Sender
+ * @notice Interface for sending data to the L2 receiver contract.
+ */
+interface IL1Sender {
+    /**
+     * @notice Sends data to the L2 receiver contract.
+     * @param target The address of the target contract on L2.
+     * @param data The data to be sent to the target contract.
+     */
+    function sendData(address target, bytes calldata data) external;
+}

contracts/contracts/coordination/IL2Receiver.sol

@@ -0,0 +1,15 @@
+// SPDX-License-Identifier: AGPL-3.0-or-later
+
+pragma solidity ^0.8.0;
+
+/**
+ * @title IL2Receiver
+ * @notice Interface for receiving data from the L1 sender contract.
+ */
+interface IL2Receiver {
+    /**
+     * @notice Receives data from the L1 sender contract.
+     * @param data The data sent from the L1 sender contract.
+     */
+    function recvData(bytes calldata data) external;
+}

contracts/contracts/coordination/ISigningCoordinatorChild.sol

@@ -0,0 +1,31 @@
+// SPDX-License-Identifier: AGPL-3.0-or-later
+
+pragma solidity ^0.8.0;
+
+/**
+ * @title ISigningCoordinatorChild
+ * @notice Interface for x-chain interactions from SigningCoordinator to Child
+ */
+interface ISigningCoordinatorChild {
+    event CohortMultisigDeployed(uint32 indexed cohortId, address multisig);
+    event CohortMultisigUpdated(
+        uint32 indexed cohortId,
+        address multisig,
+        address[] signers,
+        uint16 threshold,
+        bool clearSigners
+    );
+
+    function deployCohortMultiSig(
+        uint32 cohortId,
+        address[] calldata signers,
+        uint16 threshold
+    ) external;
+
+    function updateMultiSigParameters(
+        uint32 cohortId,
+        address[] calldata signers,
+        uint16 threshold,
+        bool clearSigners
+    ) external;
+}

contracts/contracts/coordination/IThresholdSigningMultisig.sol

@@ -0,0 +1,13 @@
+// SPDX-License-Identifier: AGPL-3.0-or-later
+
+pragma solidity ^0.8.0;
+
+interface IThresholdSigningMultisig {
+    function initialize(address[] memory, uint16, address) external;
+
+    function updateMultiSigParameters(
+        address[] calldata signers,
+        uint16 threshold,
+        bool clearSigners
+    ) external;
+}

contracts/contracts/coordination/OpL1Sender.sol

@@ -0,0 +1,50 @@
+// SPDX-License-Identifier: AGPL-3.0-or-later
+
+pragma solidity ^0.8.0;
+
+import "@openzeppelin-upgradeable/contracts/proxy/utils/Initializable.sol";
+import "./IL1Sender.sol";
+import "./IL2Receiver.sol";
+
+interface ICrossDomainMessenger {
+    function sendMessage(address target, bytes calldata message, uint32 gasLimit) external;
+}
+
+/**
+ * @title OpL1Sender
+ * @notice Optimism-based contract responsible for sending data
+ *         to the L2 receiver contract via the bridge messenger.
+ */
+contract OpL1Sender is IL1Sender, Initializable {
+    ICrossDomainMessenger public immutable messenger;
+    address public immutable dispatcher;
+    uint32 public immutable gasLimit;
+    IL2Receiver public l2Receiver;
+
+    /**
+     * @param _dispatcher The address of the dispatcher contract.
+     * @param _messenger The address of the CrossDomainMessenger contract.
+     * @param _gasLimit The gas limit for the message.
+     */
+    constructor(address _dispatcher, ICrossDomainMessenger _messenger, uint32 _gasLimit) {
+        dispatcher = _dispatcher;
+        messenger = _messenger;
+        gasLimit = _gasLimit;
+    }
+
+    function initialize(IL2Receiver _l2Receiver) external initializer {
+        l2Receiver = _l2Receiver;
+    }
+
+    /**
+     * @notice Sends data to the L2 receiver contract via the messenger.
+     * @param target The address of the target contract on L2.
+     * @param data The data to be sent to the target contract.
+     */
+    function sendData(address target, bytes calldata data) external {
+        require(dispatcher == msg.sender, "Unauthorized caller");
+        bytes memory payload = abi.encode(target, data);
+        bytes memory callData = abi.encodeWithSelector(l2Receiver.recvData.selector, payload);
+        messenger.sendMessage(address(l2Receiver), callData, gasLimit);
+    }
+}

contracts/contracts/coordination/OpL2Receiver.sol

@@ -0,0 +1,50 @@
+// SPDX-License-Identifier: AGPL-3.0-or-later
+
+pragma solidity ^0.8.0;
+
+import "@openzeppelin-upgradeable/contracts/proxy/utils/Initializable.sol";
+import "./IL2Receiver.sol";
+
+interface ICrossDomainMessenger {
+    function xDomainMessageSender() external view returns (address);
+}
+
+/**
+ * @title OpL2Receiver
+ * @notice Contract is used to receive data from the L1 sender contract via the bridge messenger.
+ */
+contract OpL2Receiver is IL2Receiver, Initializable {
+    address public immutable messenger;
+    address public l1Sender;
+
+    event Executed(address target, bytes result);
+
+    /**
+     * @param _messenger The address of the CrossDomainMessenger contract.
+     */
+    constructor(address _messenger) {
+        messenger = _messenger;
+    }
+
+    function initialize(address _l1Sender) external initializer {
+        l1Sender = _l1Sender;
+    }
+
+    /**
+     * @notice Receives data from the L1 sender contract via the messenger.
+     * @param data The data sent from the L1 sender contract.
+     */
+    function recvData(bytes calldata data) external {
+        require(messenger == msg.sender, "Not from messenger");
+        require(
+            l1Sender == ICrossDomainMessenger(messenger).xDomainMessageSender(),
+            "Invalid sender"
+        );
+        (address target, bytes memory callData) = abi.decode(data, (address, bytes));
+        // solhint-disable-next-line avoid-low-level-calls
+        (bool success, bytes memory result) = target.call(callData);
+        require(success, "L2 Receiver Execution failed");
+
+        emit Executed(target, result);
+    }
+}